Mac Geekery

System Events, introduced with Mac OS X 10.3, is what assistive devices use in Mac OS X. It also allows AppleScript to control GUI applications directly through UI Scripting.

With the release of Mac OS X 10.4, Apple includes the ability to adjust the behavior of the modifier keys on the keyboard in the Keyboard & Mouse system preferences. This becomes useful if you use a PC-style keyboard with your Mac, like I do with my iBook.

We’re combining the two to do something useful for switching between a PC style keyboard and a Mac style keyboard.

The reason this is useful on the PC-style keyboards is that the placement of the equivalent of the Command and Option keys (Windows and Alt, respectively) have their placement switched. It can be quite annoying to have to change your keystrokes on a frequent basis or having to remember to go into System Preferences and change the keyboard behavior.

Enter AppleScript, and System Events. In this case, I am using UI Scripting to automate the changing of the Keyboard & Mouse System Preferences. (Yes, I could hunt around for a while and determine which property list file and which settings to manipulate, but this was more fun for now.)

To get started with UI Scripting, you can review Apple’s documentation on the subject.

Be sure to download the UI Element Inspector, as this will allow you to see GUI elements. There are a few gotchas and pitfalls, as pwith any scripting language, but these seem more based on how the developer decided to code their UI.

Additionally, you will need to activate the UI Scripting ability. The instructions are also linked from the GUI Scripting page given above.

Play around with the UI Element inspector, as this will be your primary tool in discovering how to automate your applications.

There are a couple of things to note - menus brought up by Pop Up buttons are not accessible in your AppleScript until you click the button, so you must click (via AppleScript) the pop up button, then click the item you want.

Here is the AppleScript, it will only work with 10.4 because of the Keyboard & Mouse preferences. But the UI Scripting concepts can be used with any 10.3 or higher system. Paste this into Script Editor make sure it compiles before saving this as an application or application bundle. The only problems will likely be formatting, so make sure each “click” line is on a single, non-wrapped line.

-- UI Scripting Demonstration
--
-- Modify Keyboard System Preferences to swap the Option (Alt) and Command (Windows) keys
-- so their placement on the keyboard matches that of the standard Macintosh keyboard. This
-- will also allow us to change the preferences back so the keys go back to normal
-- when the PC keyboard is disconnected.

on setKeyboard(keyboardType)
  tell application "System Events"
    get properties
    tell process "System Preferences"
      -- click "Modifier Keys..." at bottom of Keyboard tab
      click button "Modifier Keys…" of tab group 1 of window "Keyboard & Mouse"

      if keyboardType is equal to "Macintosh" then
        -- click "Restore Defaults" on the sheet
        click button "Restore Defaults" of sheet 1 of window "Keyboard & Mouse"

      else if keyboardType is equal to "PC" then
         -- click the pop up button menu "Option", this menu does not exist until it is clicked in the GUI
         click pop up button 3 of sheet 1 of window "Keyboard & Mouse"
         -- click "Command" of the pop up menu
         click menu item 4 of menu 1 of pop up button 3 of sheet 1 of window "Keyboard & Mouse"

         -- delay briefly
         delay 1

        -- click the pop up button menu "Command", this menu does not exist until it is clicked in the GUI
        click pop up button 4 of sheet 1 of window "Keyboard & Mouse"
        -- click "Option" of the pop up menu
        click menu item 3 of menu 1 of pop up button 4 of sheet 1 of window "Keyboard & Mouse"
      end if

      -- click "OK" to dismiss the sheet
      click button "OK" of sheet 1 of window "Keyboard & Mouse"
    end tell
  end tell
end setKeyboard

-- main script; preset desiredKeyboard to "Macintosh"
set desiredKeyboard to "Macintosh"

-- get users input; we're waiting until selection
display dialog "Which keyboard type?"
  buttons {"Macintosh", "PC"}
  default button "Macintosh"

-- set desiredKeyboard to "PC" if they picked "PC"
if button returned of result = "PC" then
  set desiredKeyboard to "PC"
end if

-- activate System Preferences
tell application "System Preferences"
  activate
  set current pane to pane "com.apple.preference.keyboard"
end tell

-- call subroutine with desired keyboard type
setKeyboard(desiredKeyboard)

-- quit from system preferences
tell application "System Preferences"
  quit
end tell

Edited: 2005-04-30 11:30 CDT for clarification